Mutator Class

Класс Mutator расширяет (extends) класс Info. Ниже следует список всех переменных (а также их назначения, которые мне удалось выяснить) и функций с подробным их описанием.

Переменные

Функции

Как Вы заметили, в классе Mutator всего лишь 5 переменных и 14 функций. Тем не менее, в силу наследования класса Info (который, в свою очередь, наследует класс Actor), Вам становятся доступны многие другие переменные и функции. Наиболее важной из них является функция PostBeginPlay(). Давайте рассмотрим мутатор Spectre в качестве примера:

// Spectre
// Модифицированная версия мутатора GhostBoy
class Spectre extends Mutator; 

var bool Initialized; 

function PostBeginPlay() {

  if (Initialized) return; 

  Initialized = True; 

  Level.Game.RegisterDamageMutator(Self);
} 

function ScoreKill(Pawn Killer, Pawn Other) {

  // если у нас появился победитель, увеличим его glowing
  // у жертвы сбросим glowing на исходное значение
  if ((Killer != Other) && (Other != None) && (Killer != None)) {

    Killer.ScaleGlow += 0.2;
    Other.ScaleGlow = 1.5;
  } 

  // при суициде установим игроку то, что он заслужил :)
  if ((Other != None) && ((Killer == None) || (Killer == Other))) Other.ScaleGlow = 1.5; 

  // установим значение видимости (visibility) для того, чтобы боты нормально ее воспринимали
  Other.Visibility = Other.Default.Visibility * Other.ScaleGlow;
  Killer.Visibility = Killer.Default.Visibility * Killer.ScaleGlow; 

  // вызовем родительский ScoreKill для последующей обычной обработки убийцы и трупа
  Super.ScoreKill(Killer, Other);
} 

function bool CheckReplacement( actor Other, out byte bSuperRelevant) {

  // игроки, боты и каркасы (carcasses) (включая джибсы) должны также быть невидимыми
  if ( Other.IsA('Pawn') || Other.IsA('Carcass')) Other.Style = STY_Translucent; 

  // пикапы, дающие невидимость несколько неуместны
  // поэтому просто избавимся от них...
  if (Other.IsA('Invisibility')) return false; 

  return true;
} 

function MutatorTakeDamage(out int ActualDamage, Pawn Victim, Pawn InstigatedBy,
 out Vector HitLocation, out Vector Momentum, name DamageType) {

  local float dglow; 

  // уменьшаем glowing жертвы
  dglow = float(ActualDamage) / 70.0;
  if (dglow <= 0.1) dglow = 0.1;
  Victim.ScaleGlow -= dglow;
  if (Victim.ScaleGlow <= 0.1) Victim.ScaleGlow = 0.1; 

  // увеличиваем glowing атакующего
  if (InstigatedBy != Victim) InstigatedBy.ScaleGlow += dglow; 

  // установим значение видимости (visibility) для того, чтобы боты нормально ее воспринимали
  Victim.Visibility = Victim.Default.Visibility * Victim.ScaleGlow;
  InstigatedBy.Visibility = InstigatedBy.Default.Visibility * InstigatedBy.ScaleGlow;
  Super.MutatorTakeDamage(ActualDamage, Victim, InstigatedBy, HitLocation, Momentum, DamageType);
}

Пояснение

Начнем с самого начала. Первое, что мы делаем - объявляем класс. Честно говоря, мы просто наследуем/расширяем (extending) класс Mutator. Затем следует объявление переменных. Все переменные, объявленные вне пределов функций являются глобальными и статичными относительно этого объекта (класса) с момента его создания. Ниже следует функция PostBeginPlay(). PostBeginPlay() вызывается после того, как игра полностью подготовлена для запуска (т.е. все объекты проинициализированы, созданы, отслежены) и игра начнется после того, как мутатор вернется из этой функции (точнее, после того как все классы вернутся из этой функции). По некоторым причинам класс Mutator вызывает эту функцию дважды. Для того, чтобы избежать повторной инициализации, используется глобальная логическая переменная-флаг, показывающая вызывалась ли уже эта функция или нет. Единственная инициализация, которая происходит в этой функции, регистрирует данный мутатор в качестве мутатора повреждений, в результате чего, при нанесении кому-либо повреждения, движок будет вызывать функцию MutatorTakeDamage(). Обычно все глобальные переменные инициализируются именно в PostBeginPlay(). Не смотря на то, что движок игры инициализирует все объекты значениями по умолчанию, лучше застраховаться и произвести их инициализацию исходными значениями (надежнее сделать параноидальные проверки переменным, гарантирующие защиту от потенциальных ошибок).

Далее следует функция ScoreKill(). Эта функция вызывается любым типом мутаторов, поэтому это лучшее место, где можно сделать что-то особенное двум актерам: убийце (Killer) и жертве (Other). Объекты/свойства игрока не удаляются, когда он умирает, а просто "сбрасываются" (reset) на исходные значения. Тем не менее, движок берет на себя ответственность только за некоторые свойства, которые он и восстанавливает при респавне (respawn). Вот здесь Вы и можете произвести сброс/модификацию/настройку любых свойств игрока/актера. Следующая функция: CheckReplacement(). Вызов этой функции происходит для каждого актера при добавлении его в уровень. Если Вам не по душе присутствие какого либо актера/объекта на карте, то эта функция все уладит. Возвращая значение false, Вы тем самым говорите движку избавиться от этого актера.

И, наконец, сердце этого мутатора - функция MutatorTakeDamage(). Вследствие того, что этот мутатор был зарегистрирован в качестве мутатора повреждений в PostBeginPlay(), каждый раз, когда игроку/боту "вот-вот будет нанесен урон" вызывается эта функция. Это позволяет мутатору самому обработать переданные этой функции переменные: т.е. величину урона, место, куда попал снаряд (hit location) или вызвать другие процессы, основываясь на информации, полученной этой функцией, например, поменять значение невидимости, в зависимости от количества полученного повреждения, что и делает вышеописанный мутатор.

Автор

Pfhoenix
Источник: www.unrealscript.com
Перевод сделан 32_Pistoleta